'*********************************************
'* Name       : Turn.bas                     *
'* Author     : SSh                          *
'* MCU        : PIC12F675                    *
'* OSC        : Internal, 4MHz               *
'* Date       : 07.03.2010                   *
'* Compiler   : PicBasic Pro 2.60            *
'* Description: Turn signal one-touch system *
'*********************************************
' +5V     - 1 -|Vdd   GND|- 8  - Ground
'RightIn  - 2 -|GP5   GP0|- 7  - Rear
'LeftIn   - 3 -|GP4   GP1|- 6  - RightOut
'+ 10kOhn - 4 -|MCLR  GP2|- 5  - LeftOut
'****************************************************************************
***
' ## Set MCU & OSC - Internal, GP4 - I/O, GP5 - I/O ##
@ DEVICE pic12F675, INTRC_OSC_NOCLKOUT

DEFINE OSC 4               ' Internal Freq. 4 MHz

'Variables
Left    VAR WORD            
Right   VAR WORD            

' I/O Ports
LeftIn   var GPIO.4        
LeftOut  var GPIO.2
RightIn  Var GPIO.5
RightOut var GPIO.1
Haz      Var GPIO.0

'Constants
PulseTime con 3000         ' Delay time = 3s, 3...4 pulses

TRISIO = %111001           ' RA1, RA2 - Output
ANSEL  = 0                 ' All pins - digital
CMCON  = %00000111         ' Comparators - Off
GPIO = 0

pause 500                  ' Start-time pause

' ##################################
' ### Main part, working forewer ###
' ##################################

main:
PULSIN RightIn, 1, Right    ' Look for pulse
  if Right < 8 Then         ' Pulse not found
     gosub RightTurn        ' Turn on right turn-signal
  Endif
PULSIN LeftIn, 1, Left
  if Left < 8 Then          ' Turn on left turn signal
     gosub LeftTurn
  Endif

  If Haz = 0 then
     gosub hazard
  endif

GOTO main                       ' Loop
' ### End of main part ###

' ###################
' ### Subroutines ###
' ###################

RightTurn:
  RightOut = 1
  pause PulseTime
  RightOut = 0
lloop:
PULSIN RightIn, 1, Right
  if Right < 8 Then
     goto lloop
  Endif
return

LeftTurn:
  LeftOut = 1
  pause PulseTime
  LeftOut = 0
rloop:
PULSIN LeftIn, 1, Left
  if Left < 8 Then
     goto rloop
  Endif
return

hazard:
hloop:
  if Haz = 0 then
     RightOut = 1
     LeftOut = 1
     goto hloop
  else
     RightOut = 0
     LeftOut = 0
  endif
return

        END ' ***** End of Program *****